[VarDef,amountFS,0]//amount for Focal Shift
[VarDef,incFS,2]//increment for Focal Shift
[VarDef,amountZI,0]//amount for Z Intensity
[VarDef,incZI,2]//increment for Z Intensity

//load the Focal Shift data if the file exists
[If,[FileExists,"HotKeyFocalShiftData.zvr"],
  [VarLoad,incFS,"HotKeyFocalShiftData.zvr"]
 ,
  //no file, set increment
  [VarSet,incFS,2]
]

//load the Z Intensity data if the file exists
[If,[FileExists,"HotKeyZIntensityData.zvr"],
  [VarLoad,incZI,"HotKeyZIntensityData.zvr"]
 ,
  //no file, set increment
  [VarSet,incZI,2]
]
  
  

//**********INTERFACE********************
    
//define the sub-palette   
[ISubPalette,"ZPlugin:Misc Utilities "]


//define button for decreasing Focal Shift
[IButton,"ZPlugin:Misc Utilities :<<Focal S","Decrease Focal Shift by amount set in Focal Shift Increment slider",
	[IShowActions,0]	
	//get the current Focal Shift setting
	[VarSet,amountFS,[IGet,"Draw:Focal Shift"]]
	//reduce by the increment
	[VarSet,amountFS,amountFS-[IGet,"ZPlugin:Misc Utilities:Focal Shift Increment"]]
	//adjust for minimum value for Focal Shift
	[If,amountFS < -100,[VarSet,amountFS,-100]]	
	//set new value
	[ISet,"Draw:Focal Shift",amountFS]			
,,.5]//.5 is half palette width


//define button for increasing Focal Shift
[IButton,"ZPlugin:Misc Utilities :Focal S>>","Increase Focal Shift by amount set in Focal Shift Increment slider",
    [IShowActions,0] 
    //get the current Focal Shift setting      
    [VarSet,amountFS,[IGet,"Draw:Focal Shift"]] 
    //increase by the increment      
    [VarSet,amountFS,amountFS+[IGet,"ZPlugin:Misc Utilities:Focal Shift Increment"]]        
    //adjust for maximum value for Focal Shift
	  [If,amountFS > 100,[VarSet,amountFS,100]]	
	  //set new value    
    [ISet,"Draw:Focal Shift",amountFS]        
,,.5]//.5 is half palette width


[ISlider,"ZPlugin:Misc Utilities :Focal Shift Increment",[Val,incFS],1,1,20
,"Focal Shift adjustment increment...(press Alt for more)
\n\Cff9923Set to the amount you wish the Focal Shift to increase or decrease
 using the hotkeys.\nWhen Focal Shift is 10 or below, increments will be 1."
,//commands for when slider adjusted
  //set increment variable from slider
  [VarSet,incFS,[IGet,"ZPlugin:Misc Utilities:Focal Shift Increment"]]
  //save the variable data to file
  [VarSave,incFS,"HotKeyFocalShiftData.zvr"]
,,1]



[IButton,"ZPlugin:Misc Utilities :<<Z Intens","Decrease Z Intensity by amount set in Z Intensity Increment slider",
	[IShowActions,0]	
	//get the current Z Intensity setting 
	[VarSet,amountZI,[IGet,"Draw:Z Intensity"]]
	//decrease by the increment or by 1 if current value less than 10
		[If,(amountZI>10)&&(amountZI < (10+[IGet,"ZPlugin:Misc Utilities:Z Intensity Increment"])),			
			[VarSet,amountZI,10]
		,
			[If,amountZI<=10,
				[VarDec,amountZI]
			,
			[VarSet,amountZI,amountZI-[IGet,"ZPlugin:Misc Utilities:Z Intensity Increment"]]
			]
		]
		//adjust for minimum value for Z Intensity
		[If,amountZI < 0,[VarSet,amountZI,0]]	
		//set new value
		[ISet,"Draw:Z Intensity",amountZI]			
,,.5]




[IButton,"ZPlugin:Misc Utilities :Z Intens>>","Increase Z Intensity by amount set in Z Intensity Increment slider",
    [IShowActions,0]
    //get the current Z Intensity setting        
    [VarSet,amountZI,[IGet,"Draw:Z Intensity"]]
    //increase by the increment or by 1 if current value less than 10
    [If,amountZI < 10,
        [VarInc,amountZI]
    ,
        [VarSet,amountZI,amountZI+[IGet,"ZPlugin:Misc Utilities:Z Intensity Increment"]]
    ]        		
    //adjust for maximum value for Z Intensity   		
    [If,amountZI > 100,[VarSet,amountZI,100]]	
    //set new value    
    [ISet,"Draw:Z Intensity",amountZI]        
,,.5]


[ISlider,"ZPlugin:Misc Utilities :Z Intensity Increment",[Val,incZI],1,1,20
,"Z Intensity adjustment increment...(press Alt for more)
\n\Cff9923Set to the amount you wish the Z Intensity to increase or decrease
 using the hotkeys.\nWhen Z Intensity is 10 or below, increments will be 1."
,//commands for when slider adjusted
  //set increment variable from slider
  [VarSet,incZI,[IGet,"ZPlugin:Misc Utilities:Z Intensity Increment"]]
  //save the variable data to file
  [VarSave,incZI,"HotKeyZIntensityData.zvr"]
,,1]